Topics

1

General coding questions / Timing is everything but how?

« on: November 04, 2012 »

Imagine I'm using a basic language to code a demo. It's fine, it's structural but how do I go about the timing? Imagine I want a scene to last 10 seconds and then 20 seconds on the next? Functions for each and delays? 

2

General chat / christmas competition

« on: November 04, 2012 »

Greetings from the beery side,
I'm looking forward to the Xmas competition. Pretty much christmas and world cups are all I have the enthusiasm to produce something for.My last shameful release was 6 years ago ! http://pouet.net/prod.php?which=28334&howmanycomments=-1

What code is good? Are the competitions wild?



 

3

General coding questions / Looking for White noise / tv static algorithms

« on: October 09, 2006 »

Wondering if anyone has any pseudo code or theories for coding white noise aka. tv static.
- Black background.
- random White/grey pixels?

4

Useful links / Blitzbasic and BlitzMax Demo effects tutorials

« on: September 28, 2006 »

Tons of Blitz3d/Plus demos effects tutorials:
http://www.zac-interactive.dk/tutorials/tutorials.htm


BlitzPlus / Blitz3D tutorials:
Bob Snake
Color Gradient Interpolation
Image Alpha   Melt Effect
Parallax Starfield   B3D: Particles 3D Part 1
B3D: Particles 3D Part 2   Plasma
Raster/Copper Bars   Reflection Effect
Screen Fader   Bitmap Scroller Horizontal
Bitmap Scroller Sinus   Bitmap Scroller Vertical
Sine-Lines   Vector Bobs
Vector Dots   Vector Dot Tunnel
Vector Wireframe   Vector Wireframe Hidden
Vector Filled   
BlitzMax tutorials:
Bitmap Scroller, Vertical   Bob Snake

Lots from our very own Scott here http://www.scottshaver2000.com/site/template/template.php?page=examples

5

C / C++ /C# / Fit : cross platform c++ code archive

« on: August 22, 2006 »

Fit http://pouet.net/groups.php?which=409 make a lot of lovely demo and release all their source code as a bonus! Great for studying !  http://www.kameli.net/fit/index.html

6

Blitz / BlitzMax : Novell screensaver routine[BMAX]

« on: August 19, 2006 »

Got it ported from BlitzBasic to BlitzMax code below

Code: [Select]

' Version 2.0
' Februar 2001
' Made by Einar Wedoe
' Programtype: Novell server screensaver look-a-like
' Use arrow-keys to change speed and length of tail !

Import "bbtype.bmx"
Import "bbvkey.bmx"
AppTitle ="Novell screensaver"

Graphics 800,600,32 ' Sett Grphics mode
SetColor 255,0,0 ' Set Color
HideMouse()
Global x=400 ' Leader-dot-x-pos
Global y=300 ' Leader-dot-y-pos
Global direction=1 ' Direction variable
Global directiontmp=0 ' Temporary direction variable
Global round=10 ' How long between every change of direction ?
Global roundcount=0 ' Counter for the rounds
Global speed#=3 ' Speed
Global speedcount=1 ' Counter for speed
Global length=35 ' Initial tail-length
Global show=0 ' Variable for showing speed and length on screen

Global tailX[100+1] ' Tail x can be up to 1000 blocks long
Global tailY[100+1] ' Tail y can be up to 1000 blocks long

For a=1 To 100 ' Set the current tail off the screen
 tailx(a)=-20
 taily(a)=-20
Next

SeedRnd MilliSecs() ' Make random even more random
Global frametimer=CreateTimer(75) ' Set up timer to make everything run nice on all PC's



'----------------------------------------- MAIN -----------------------------
#start ' Mainloop

While Not VKeyHit(1) ' Loop until ESC is pressed
WaitTimer(frametimer) ' Wait....
Cls ' Clean up
novell() ' Do stuff
changespeedortail() ' Wanna change speed or/and tail ?
Flip ' Change buffer
Wend ' Next round please
End


'----------------------------------------- NOVELL ----------------------------
Function novell() ' Start the function to actually put something on the screen
speedcount=speedcount+1
 If speed > speedcount Then Goto draw

Select direction ' Moving blocks about
Case 1
x=x-11
y=y-13

Case 2
y=y-13

Case 3
y=y-13
x=x+11

Case 4
x=x+11

Case 5
x=x+11
y=y+13

Case 6
y=y+13

Case 7
x=x-11
y=y+13

Case 8
x=x-11
End Select

speedcount=0
border ' Check if we hit the border
If direction=100 Then  roundcount=round+1 ' If we did, do something about it !
directiontest ' Check if time for change of direction

For a=length To 1 Step-1 ' Move the x and y down the line
tailx(a+1)=tailx(a)
taily(a+1)=taily(a)
Next
tailx(1)=x ' Put x in the end of the line
taily(1)=y ' Put y in the end of the line


#draw


colordrop=255/length ' Find how much to drop color pr. rect
colortmp=0 ' Set color to 0
For a=length To 1 Step -1 ' Draw tail
SetColor colortmp,0,0 ' Set color for current rect
  DrawRect tailx(a),taily(a),10,12 ' Draw current rect
  colortmp=colortmp+colordrop ' Count up color
Next


End Function


'----------------------------------------- BORDER ----------------------
Function border() ' Set direction to 100 if border is reached
Select direction
Case 1
If x < 15 Or y < 5 Then direction=100
Case 2
If y < 5 Then direction=100
Case 3
If x > 780 Or y < 5 Then direction=100
Case 4
If x > 780 Then direction=100
Case 5
If x > 780 Or y > 585 Then direction=100
Case 6
If y > 585 Then direction=100
Case 7
If x < 15 Or y > 585 Then direction=100
Case 8
If x < 15 Then direction=100
End Select
End Function
'-----------------------------------------
Function directiontest() ' Find new direction if it's time
roundcount=roundcount+1
If roundcount > round Then ' Time for a change
  directiontmp=direction ' Temporary store old direction
#findnewdirection   direction=Rand(8) ' Find new direction
      If direction=directiontmp Then Goto findnewdirection ' If it's the same then try again
  border ' Check for border
  If direction=100 Then Goto findnewdirection ' Bounce border
  roundcount=0 ' Reset counter
  round=Rand(20) ' Set new point for change of direction again
  EndIf


End Function
'-----------------------------------------
Function changespeedortail() ' Change things
If VKeyDown(200) And length < 99 Then ' Add length of tail if arrow-up is pressed
length=length+1 ' All length by 1
tailx(length)=-20 ' Set new x-part of tail offscreen
taily(length)=-20 ' Set new x-part of tail offscreen
show=255 ' Set show variable to print to scren for 200 rasters
EndIf
If VKeyDown(208) And length > 5 Then ' Decrease length of tail if arrow down is pressed
length=length-1 ' Dec by 1
show=255 ' Set show variable to print to scren for 200 rasters
EndIf
If VKeyDown(203) And speed < 10 Then ' Add speed if arrow-right is pressed
speed=speed+0.05 ' Add speed by 0.05
show=255 ' Set show variable to print to scren for 200 rasters
EndIf
If VKeyDown(205) And speed > 1 Then ' Dec speed if arrow-left is pressed
speed=speed-0.05 ' Dec speed by 0.05
show=255 ' Set show variable to print to scren for 200 rasters
EndIf
show=show-1 ' Decrease show-variable
If show < 0 Then show=0 ' If show drops below zero keep it on zero
If show > 0 Then ' If show-variable is activated
SetColor show,0,0 ' Fade away text
DrawText "Length: "+length,0,0 ' Show length
DrawText "Speed:  "+Int(10-speed+1),0,12 ' Show speed but since speed is oposite of normal recalculate it
EndIf

End Function
'-----------------------------------------

7

Blitz / BlitzBasic : Soft Sine Scroller[BB2D]

« on: August 18, 2006 »

"If there was one thing that really was a "must" on almost every demo on the Amiga-scene, that would have to be a soft sine scroller.
Therefore I made one for you to study. This code is NOT optimized for speed, it was written to be as easy to understand as possible ! There are at least a 100 ways to do a soft-sine scroller, this is one of them ! (Using up to 900 sprites) Charset is taken from the "Oldschool"-example in the BB help-file by Shane R. Monore. Using tables for sinus would improve performance a LOT since then there would be no use for the floats (which are really slow). Maybe I'll make a table-version if anyone bothers to bug me about it ;-) I packed it all i a zip file for this one since a gfx-file is needed for the example. Source included !"

BB-Ver. 1.48

Posted with permission of the author Einar Wedoe of http://blitzbasic.no/
Exe here http://blitzbasic.no/div/soft-sine.zip

Code: [Select]

AppTitle "Soft Sine Scroller"
;-----------------------------------------------
; Version Beta 1
; May 2001
; Made by Einar Wedøe
; Programtype: Soft Sinus Scroller
;-----------------------------------------------
Graphics 800,600,16,1
Dim degree#(5) ; Dim up sinus-waves
Dim startdegree#(5) ; Start for sine on each frame
Dim count#(5) ; Dim up sinus-counters
Dim wavespeed#(5)

Global speed=2 ; Speed of scroller (max 5)
Global numberofsines=3 ; Number of sines to calculate y (max 5)

For a=1 To 5 ; Ranomize sinus
 count#(a)=Rnd(-2,2)
 wavespeed#(a)=Rnd(-2,2)
Next

Type softletter ; Type for each pixel of all letters
    Field x,y ; X and Y pos
Field frame ; Wich frame ?
End Type

Global alphabet=LoadAnimImage("finalfont.png",1,27,0,690) ; Loadfont
Global widthcount=0 ; Count letterwith
Global currentletterwith=40 ; Holds letterwith
Global scrollcount=0 ; Pointer in scrolltext-string
Global scrolltext$="" ; The text to show
Global plotsy#=0 ; Y-pos
Global textavailible$="" ; Holder for availible letters
Global sinecount=10
Dim letteroffset(35) ; Offset in bitmap for each letter
Dim letterwidth(35) ; Width of each letter

SetBuffer BackBuffer()
Color 255,255,255

Gosub initscroller ; Put scrolltext in scrolltext$-string

For a=1 To 500 ; Fill screen with emty types
  scrollcount=0  
  newletter ; to make sinuseslook right
  wave
Next



8

Blitz / BlitzBasic : Novell screensaver routine[BB2D]

« on: August 18, 2006 »

"Another blast from the past, only that a lot of people still use this oldie...I think the old screensaver from Novell is quite nice, so i remade it in BB.This can easily be converted to a "real" screensaver, use arrow keys for changes."

BB-Ver. 1.48

Posted with permission of the author Einar Wedoe of http://blitzbasic.no/
Exe here http://blitzbasic.no/div/novell.zip

Code: [Select]

AppTitle "Novell screensaver"

; Version 2.0
; Februar 2001
; Made by Einar Wedoe
; Programtype: Novell server screensaver look-a-like
; Use arrow-keys to change speed and length of tail !


Graphics 800,600,16,1 ; Sett Grphics mode
Color 255,0,0 ; Set Color

Global x=400 ; Leader-dot-x-pos
Global y=300 ; Leader-dot-y-pos
Global direction=1 ; Direction variable
Global directiontmp=0 ; Temporary direction variable
Global round=10 ; How long between every change of direction ?
Global roundcount=0 ; Counter for the rounds
Global speed#=3 ; Speed
Global speedcount=1 ; Counter for speed
Global length=35 ; Initial tail-length
Global show=0 ; Variable for showing speed and length on screen

Dim tailX(100) ; Tail x can be up to 1000 blocks long
Dim tailY(100) ; Tail y can be up to 1000 blocks long

For a=1 To 100 ; Set the current tail off the screen
 tailx(a)=-20
 taily(a)=-20
Next

SeedRnd MilliSecs() ; Make random even more random
Global frametimer=CreateTimer(75) ; Set up timer to make everything run nice on all PC's
SetBuffer BackBuffer() ; Start dobbelbuffering
;-----------------------------------------
.start ; Mainloop

While Not KeyHit(1) ; Loop until ESC is pressed
WaitTimer(frametimer) ; Wait....
Cls ; Clean up

novell ; Do stuff
changespeedortail ; Wanna change speed or/and tail ?

Flip ; Change buffer
Wend ; Next round please
End
;-----------------------------------------
Function novell() ; Start the function to actually put something on the screen
speedcount=speedcount+1
 If speed > speedcount Then Goto draw

Select direction ; Moving blocks about
Case 1
x=x-11
y=y-13

Case 2
y=y-13

Case 3
y=y-13
x=x+11

Case 4
x=x+11

Case 5
x=x+11
y=y+13

Case 6
y=y+13

Case 7
x=x-11
y=y+13

Case 8
x=x-11
End Select

speedcount=0
border ; Check if we hit the border
If direction=100 Then  roundcount=round+1 ; If we did, do something about it !
directiontest ; Check if time for change of direction

For a=length To 1 Step-1 ; Move the x and y down the line
tailx(a+1)=tailx(a)
taily(a+1)=taily(a)
Next
tailx(1)=x ; Put x in the end of the line
taily(1)=y ; Put y in the end of the line


.draw


colordrop=255/length ; Find how much to drop color pr. rect
colortmp=0 ; Set color to 0
For a=length To 1 Step -1 ; Draw tail
  Color colortmp,0,0 ; Set color for current rect
  Rect tailx(a),taily(a),10,12,1 ; Draw current rect
  colortmp=colortmp+colordrop ; Count up color
Next


End Function
;-----------------------------------------
Function border() ; Set direction to 100 if border is reached
Select direction
Case 1
If x < 15 Or y < 5 Then direction=100
Case 2
If y < 5 Then direction=100
Case 3
If x > 780 Or y < 5 Then direction=100
Case 4
If x > 780 Then direction=100
Case 5
If x > 780 Or y > 585 Then direction=100
Case 6
If y > 585 Then direction=100
Case 7
If x < 15 Or y > 585 Then direction=100
Case 8
If x < 15 Then direction=100
End Select
End Function
;-----------------------------------------
Function directiontest() ; Find new direction if it's time
roundcount=roundcount+1
If roundcount > round Then ; Time for a change
  directiontmp=direction ; Temporary store old direction
.findnewdirection   direction=Rand(8) ; Find new direction
      If direction=directiontmp Then Goto findnewdirection ; If it's the same then try again
  border ; Check for border
  If direction=100 Then Goto findnewdirection ; Bounce border
  roundcount=0 ; Reset counter
  round=Rand(20) ; Set new point for change of direction again
  EndIf


End Function
;-----------------------------------------
Function changespeedortail() ; Change things
If KeyDown(200) And length < 99 Then ; Add length of tail if arrow-up is pressed
length=length+1 ; All length by 1
tailx(length)=-20 ; Set new x-part of tail offscreen
taily(length)=-20 ; Set new x-part of tail offscreen
show=255 ; Set show variable to print to scren for 200 rasters
EndIf
If KeyDown(208) And length > 5 Then ; Decrease length of tail if arrow down is pressed
length=length-1 ; Dec by 1
show=255 ; Set show variable to print to scren for 200 rasters
EndIf
If KeyDown(203) And speed < 10 Then ; Add speed if arrow-right is pressed
speed=speed+0.05 ; Add speed by 0.05
show=255 ; Set show variable to print to scren for 200 rasters
EndIf
If KeyDown(205) And speed > 1 Then ; Dec speed if arrow-left is pressed
speed=speed-0.05 ; Dec speed by 0.05
show=255 ; Set show variable to print to scren for 200 rasters
EndIf
show=show-1 ; Decrease show-variable
If show < 0 Then show=0 ; If show drops below zero keep it on zero
If show > 0 Then ; If show-variable is activated
Color show,0,0 ; Fade away text
Text 0,0, "Length: "+length ; Show length
Text 0,12,"Speed:  "+Int(10-speed+1) ; Show speed but since speed is oposite of normal recalculate it
EndIf

End Function
;-------------------------

9

Blitz / BlitzBasic : Commodore 64 depacking screen [BB2D]

« on: August 18, 2006 »

Similar in concept to the BlitzMax code previously posted : http://dbfinteractive.com/index.php?topic=421.0

Posted with permission of the author Einar Wedoe of http://blitzbasic.no/
Exe here http://blitzbasic.no/div/decrunch.zip

Code: [Select]

AppTitle "Decrunch"

; Version 1.0
; April 2001
; Made by Einar Wedøe
; Programtype: Blast from the past :-)
; Does nothing at all but simulate a decrunch routine from the C64 days !

Graphics 640,480,16,1

Global font1
font1=LoadFont ("verdana",20,False,False,False) ; Sett up font
SetFont font1

SetBuffer BackBuffer() ; Start with the backbuffer()
Global frametimer=CreateTimer(75) ; Set up timer to make everything run nice on all PC's

;---------------------------
.start ; Mainloop

While Not KeyHit(1) ; Loop until ESC is pressed
WaitTimer(frametimer) ; Wait....
Cls ; Clean up
 flash ; Do the flash
  Color 255,255,255 ; Set color to white for the text
    Text 240,235,"Decrunching..." ; Set dumy-text
Flip ; Change buffer
Wend ; Next round please
End ; Tha's it !

;---------------------------
Function flash() ; Flashroutine
a=0 ; Reset counter
.flashloop
Color Rand(255),Rand(255),Rand(255) ; Set color randomly
 tmp=Rand(10) ; Set size of next line random
  Rect 0,a,640,tmp ; Draw the rect (the next flashline)
   a=a+tmp ; Increase counter with height of the rect
    If a > 480 Then Goto endflash ; Are we at the bottom yet ?
   Goto flashloop ; If not make another rectangle
.endflash
End Function ; Thats it for this frame
;----------------------------

10

General coding questions / Anyone recomend an OpenGL book?

« on: August 14, 2006 »

Looking for pretty much a beginners book to OpenGL. Lots of them out there on amazon and am therefore looking for recomendations. Saw this demo today http://www.pouet.net/prod.php?which=16327 which reminded me to start learning OpenGL  

11

General coding questions / Devlib : anyone using it?

« on: August 06, 2006 »

http://www.devlib-central.org/mambo/
DevLib is an object-oriented framework written in pure C++. It is designed to make multimedia productions (games, screen-savers, demos..) easier and more intuitive to write. Consequences are a complete abstraction of resources management (fonts, images, 3D meshes, files, zip-archives, sounds..) and rendering operations through 3D hardware.
The goal of the library is to provide a set of routines used in almost all the projects. It doesn't try to re-invent the wheel, does not implements everything possible into the huge programming-world, but makes use of the following well-known libraries : DevIL, FreeType 2, LUA, ODE, libjpeg, libmpeg2, libpng, TinyXML, unzip, ZLib, SDL, DirectX 9, FMOD, GLEW and finally STL.


Came across this library today, appears to be very impressive. Wondering if anyone is using it as the website is stale and their forums full of spam. 

12

General chat / Rss feed?

« on: July 12, 2006 »

Wondering if there is an rss feed for this board? I know SMF 1.0.7 has the capabilities but can't seem to find it here . thanks .

13

Useful links / Flastro scene

« on: July 12, 2006 »

Remakes of classics from the past http://www.flashtro.com all converted into flash. A lot of older amiga demo sceners hang around here. 

14

Blitz / BlitzMax : Sinewaves[BMAX]

« on: July 12, 2006 »

not sure who wrote this, picked it up on the BlitzMax forums. 

Code: [Select]

Graphics 800,600,32,0
SeedRnd MilliSecs()

'Variable setup
lineAngle1 = Rnd( 359 )
lineAngle2 = Rnd( 359 )
lineAngle3 = Rnd( 359 )
lineAngle4 = Rnd( 359 )
lineAngle1add = Rnd( 1, 3 )
lineAngle2add = Rnd( 1, 3 )
lineAngle3add = Rnd( 1, 3 )
lineAngle4add = Rnd( 1, 3 )
lineColor1 = 255
lineColor2 = 255
lineColor3 = 255
numberOfLines = 128
lineSpace = 2
angleChangeRate = 15
angleUpdateRate = 250
colorUpdateRate = 5000

'SetBuffer BackBuffer()
While Not KeyHit(key_escape)

Cls

' copy current angles
angle1tmp = lineAngle1
angle2tmp = lineAngle2
angle3tmp = lineAngle3
angle4tmp = lineAngle4

' set current line color
SetColor lineColor1, lineColor2, lineColor3
' loop through the number of lines
For i = 1 To numberOfLines
' find the two End points
x1 = 320 + Sin( angle1tmp ) * 199
x2 = 320 + Sin( angle2tmp ) * 199
y1 = 240 + Sin( angle3tmp ) * 199
y2 = 240 + Sin( angle4tmp ) * 199
' draw the line
DrawLine x1, y1, x2, y2
' add the Step in angle
angle1tmp = angle1tmp + lineSpace
angle2tmp = angle2tmp + lineSpace
angle3tmp = angle3tmp + lineSpace
angle4tmp = angle4tmp + lineSpace
Next

' check If its time To advance the angles
If (MilliSecs() > lastAngleChange + angleChangeRate)
lastAngleChange = MilliSecs()
lineAngle1 = lineAngle1 + lineAngle1add ; If lineAngle1 > 359 Then lineAngle1 = lineAngle1 - 360
lineAngle2 = lineAngle2 + lineAngle2add ; If lineAngle2 > 359 Then lineAngle2 = lineAngle2 - 360
lineAngle3 = lineAngle3 + lineAngle3add ; If lineAngle3 > 359 Then lineAngle3 = lineAngle3 - 360
lineAngle4 = lineAngle4 + lineAngle4add ; If lineAngle4 > 359 Then lineAngle4 = lineAngle4 - 360
End If

' check If its time To change the angle add values
If MilliSecs() > lastAngleUpdate + angleUpdateRate
lastAngleUpdate = MilliSecs()
r = Rnd( 3 )
If r = 0 Then lineAngle1add = Rnd( 1, 4 )
If r = 1 Then lineAngle2add = Rnd( 1, 4 )
If r = 2 Then lineAngle3add = Rnd( 1, 4 )
If r = 3 Then lineAngle4add = Rnd( 1, 4 )
End If

' check If its time To change the color
If MilliSecs() > lastColorUpdate + colorUpdateRate
lastColorUpdate = MilliSecs()
lineColor1 = Rnd( 50, 255 )
lineColor2 = Rnd( 50, 255 )
lineColor3 = Rnd( 50, 255 )
End If

Flip

Wend
End


15

Blitz / BlitzMax : Bob[BMAX]

« on: July 12, 2006 »

A simple bob effect. Sphere.png is attached. 

Code: [Select]

Graphics 800,600,0
 Local bobImage:TImage = LoadImage( "sphere.png" ) ' load the image we use for the bobs
MidHandleImage bobImage ' set the handle to the center

Local i:Int, bobXadd:Int, bobYadd:Int, bobUpdate

Local bobx[64], boby[64] ' setup placeholders for x and y position for the bobs
For i = 0 To 63
bobx( i ) = i * 4 Mod 360 ' space the positions out a little
boby( i ) = i * 3 Mod 360 ' using Mod to keep the numbers between 0 and 360
Next

bobXadd = 1 ' this is the values we add to move the bobs
bobYadd = 2 ' change these For different patterns

While Not KeyHit(1)

Cls

For i = 0 To 63
DrawImage bobImage, 400 + Sin( bobx[i] ) * 304, 240 + Sin( boby[i] ) * 224 ' draw the bobs onto the screen
Next

If MilliSecs() > bobsUpdate + 15 Then ' here we find the next position of the bobs
bobsUpdate = MilliSecs()
For i = 0 To 63
bobx[i] = bobx[i] + bobXadd Mod 360
boby[i] = boby[i] + bobYadd Mod 360
Next
End If

Flip

Wend
End


16

Blitz / BlitzMax : RasterBars [BMAX]

« on: July 12, 2006 »

Rasterbars, not sure who wrote them but someone on the Blitzmax forums I think.
Wikipedias info on rasterbars http://en.wikipedia.org/wiki/Raster_bar

Code: [Select]

SetGraphicsDriver GLMax2DDriver()
Graphics 640,480,0
' set randomizer
SeedRnd MilliSecs()

' bar generation And control variables
Global barHeight = 256
Global barHeightHalf = barHeight
Global barSpeed = 2
Global barPosition = 0

' Create Image For Raster Bars
'---------------------------------------------------
For i = 0 To 15
SetColor i * 16, 0, 0
DrawLine 0, i, 640, i
DrawLine 0, 31 - i, 640, 31 - i
Next

SetAlpha 0.75
Local barImage1=CreateImage(640,32,1,DYNAMICIMAGE|ALPHABLEND)

GrabImage barImage1,0,0


For i = 0 To 15
SetColor 0, i * 16, 0
DrawLine 0, i, 640, i
DrawLine 0, 31 - i, 640, 31 - i
Next
Local barImage2=CreateImage(640,32,1,DYNAMICIMAGE|ALPHABLEND)

GrabImage barImage2,0,0

For i = 0 To 15
SetColor 0, 0, i * 16
DrawLine 0, i, 640, i
DrawLine 0, 31 - i, 640, 31 - i
Next

Local barImage3=CreateImage(640,32,1,DYNAMICIMAGE|ALPHABLEND)
GrabImage barImage3,0,0

While Not KeyHit(1)
Cls
j = 0
angletemp = angle
For i = 0 To 7
Select j
Case 0
DrawImage barImage1, 0, 240 + Sin( angletemp ) * 80
Case 1
DrawImage barImage2, 0, 240 + Sin( angletemp ) * 80
Case 2
DrawImage barImage3, 0, 240 + Sin( angletemp ) * 80
End Select
j = j + 1
If j > 2 Then j = 0
angletemp = angletemp + 8
Next
angle = angle + 1
If angle > 359 Then angle = angle - 360

DrawImage barImage1, 0, barPosition
barPosition = barPosition - barSpeed
Flip
Cls
Wend
End


17

Blitz / BlitzMax : Commodore 64 depacking screen[BMAX]

« on: July 12, 2006 »

Attached source code and .exe example.
Can the mod change this forums title from blitz basic to blitz Basic/Max/3d to reflect all the languages please! 

Code: [Select]

'c64 random color loading demo
'Posted to DBF-GVY Demo Code Forum by DaD1916 scsicork@hotmail.com
'Draws
Strict

Graphics 800,600,32
HideMouse()

Repeat
Cls
C64Loading
Flip
Until KeyHit(KEY_ESCAPE)

End

Function C64Loading()
Local y=0,h
Repeat
If KeyHit(KEY_ESCAPE) End
h=Rand(5,60)
SetColor Rand(255),Rand(255),Rand(255)
DrawRect 0,y,GraphicsWidth(),h
y:+h
Until y>=GraphicsHeight()
End Function


18

Projects / Win/Mac: Hello Dad

« on: July 12, 2006 »

http://pouet.net/prod.php?which=24390  My first Win/Mac production

19

Projects / Win/Mac: My Latest prod : World Cup 2006

« on: July 12, 2006 »

http://pouet.net/prod.php?which=25496
Both windows and Mac ports.